
    ExampleApp

This is an example application that demonstrates how to use ex_fdbmonitor in both
development and production along with ecto_foundationdb. Together, these two
dependencies can be a basis for how your application state is managed across different
environments.
This README contains the comprehensive list of steps taken to construct this example, so
that the reader may follow along with their own application.
Guide
Install system dependencies
From FoundationDB Releases, choose the latest
stable release, and install the foundationdb-clients and foundationdb-server packages for your
system.
At the time of writing, a MacOS system should use FoundationDB-7.3.42_arm64.pkg
to install both foundationdb-clients and foundationdb-server.
Create the application with mix
mix new example_app --sup
cd example_app

# .gitignore
/.example_app/
/.erlfdb_sandbox/

Set up application config
This section describes a conventional way to manage application config in differing
mix environments. For now, we'll leave the config files empty, and we'll fill them in
later.
mkdir config
touch config/dev.exs config/test.exs config/prod.exs

# config/config.exs
import Config

import_config "#{config_env()}.exs"
Add :ecto_foundationdb and :ex_fdbmonitor deps
  # mix.exs
  defp deps do
  [
    {:ecto_foundationdb, "~> 0.4"},
    {:ex_fdbmonitor, "~> 0.1", only: :dev}
  ]
  end
mix deps.get
mix

You'll see a warning, which we'll address in the next step.
10:14:17.299 [warning] ExFdbmonitor starting without running fdbmonitor. At minimum, you should define `:etc_dir` and `:run_dir`, but you should also consider adding a `:bootstrap` config.
For MIX_ENV=dev
The dev.exs configuration shown here creates a working directory for FoundationDB
that is expected to be semi-permanent. That is, this FoundationDB cluster (of 1 node)
can be kept long term during development of your application. It will be in active
use when you run iex -S mix.
You can modify the directories and port(s) according to your needs.
Note: This is not a "Sandbox". Sandboxes should be reserved for
databases that are ephemeral and safe to delete at any time.
Configure ex_fdbmonitor
When your app is running with this config, it will start a single fdbserver process
and it will listen on port 5000. It uses the ssd-2 storage engine.
# config/dev.exs
import Config

config :ex_fdbmonitor,
  etc_dir: ".example_app/dev/fdb/etc",
  run_dir: ".example_app/dev/fdb/run"

config :ex_fdbmonitor,
  bootstrap: [
    conf: [
      data_dir: ".example_app/dev/fdb/data",
      log_dir: ".example_app/dev/fdb/log",
      fdbservers: [
        [port: 5000]
      ]
    ]
  ]
Verify dev FDB
To verify this config, you can run
iex -S mix

and then
iex(1)> ExFdbmonitor.Fdbcli.exec("status minimal")
{:ok, [stdout: ["The database is available.\n"]]}
which is equivalent to
fdbcli -C .example_app/dev/fdb/etc/fdb.cluster --exec "status minimal"

Creating ExampleApp.Repo
Before setting up mix test, let's make sure our app can interact with a database
via Ecto.
Add a repo.ex file:
# lib/example_app/repo.ex
defmodule ExampleApp.Repo do
  use Ecto.Repo, otp_app: :example_app, adapter: Ecto.Adapters.FoundationDB

  use EctoFoundationDB.Migrator

  def migrations(), do: []
end
Add this section to dev.exs:
# config/dev.exs
config :example_app, ExampleApp.Repo,
  open_db: &ExFdbmonitor.open_db/1
# ...
Start the Repo in your application:
# lib/example_app/application.ex
defmodule ExampleApp.Application do
  # ...
  def start(_type, _args) do
    children = [
      ExampleApp.Repo
    ]

    # ...
  end
end
Your dev environment is now ready to use.
For MIX_ENV=test
In the configuration of test.exs we're actually not using ex_fdbmonitor, and instead
using EctoFoundationDB.Sandbox. Instead of creating a FoundationDB cluster, this sandbox
manages a single fdbserver process. The port is chosen automatically, and it is not
necessary for your application to inspect this port. The sandbox will create the directory
.erlfdb_sandbox.
An alternative approach is to use ExFdbmonitor.Sandbox, which uses :local_cluster to
start additional BEAM VMs, and allows testing of multiple node configurations. You may
reference the ExUnit tests for an example of how to do that. Using EctoFoundationDB.Sandbox
is faster and simpler.
Configure test.exs
This is an important step that will ensure mix test does not connect to a FoundationDB
database that is running on your system in the default location.
# test.exs
import Config

config :example_app, ExampleApp.Repo,
  open_db: &EctoFoundationDB.Sandbox.open_db/1
Set up supporting files
We define an ExUnit Case to be used by any of your tests that require a database
connection. It's called TenantCase because it sets up a randomly generated
FoundationDB Tenant so that each Case is fully isolated in the database, which
ensures that your tests can execute concurrently.
You are encouraged to adapt this Case based on the needs of your application, but
avoid using a common tenant_id, as this will break the isolation.
Also note that EctoFoundationDB.Sandbox will delete all existing data in the tenant
at checkout time, and will delete the tenant entirely on checkin.
mkdir test/support
touch test/support/tenant_case.ex

# test/support/tenant_case.ex
defmodule ExampleApp.TenantCase do
  use ExUnit.CaseTemplate
  alias Ecto.UUID
  alias EctoFoundationDB.Sandbox
  alias ExampleApp.Repo

  setup do
    tenant_id = UUID.autogenerate()
    tenant = Sandbox.checkout(Repo, tenant_id, [])

    on_exit(fn ->
      Sandbox.checkin(Repo, tenant_id)
    end)

    {:ok, [tenant_id: tenant_id, tenant: tenant]}
  end
end
The following edits to mix.exs will ensure your new Case is compiled by mix.
# mix.exs
def project do
  [
    app: :example_app,
    # ...
    elixirc_paths: elixirc_paths(Mix.env()),
    # ...
  ]
end
# ...
defp elixirc_paths(:test), do: ["lib", "test/support"]
defp elixirc_paths(_), do: ["lib"]
Finally, we can write our test, which simply runs a trivial transaction. Of course,
this is where you'll put test logic that is relevant to your application.
# test/example_app_test.exs
defmodule ExampleAppTest do
  use ExampleApp.TenantCase
  test "greets the world", context do
    tenant = context[:tenant]
    assert :ok = ExampleApp.Repo.transaction(fn -> :ok end, prefix: tenant)
  end
end
You should now be able to run mix test successfully. You can safely delete the .erlfdb_sandbox directory
at any time throughout development.
For MIX_ENV=prod
In production, you have a choice. It's likely that you'll want to host FoundationDB on infrastructure that
is separated from your application (Conventional), but there are other configurations that might be
interesting to you (Radical).
Conventional: connect to remote database
Simply construct prod.exs like so:
# config/prod.exs
import Config

config :example_app, ExampleApp.Repo,
  cluster_file: "/etc/foundationdb/fdb.cluster"
The :cluster_file option should identify a file on the filesystem. Your application should have both read
and write access to this file. The contents of this file are generated by the FoundationDB server and should not
be changed by hand. If you don't have this file, then you must copy it from the FoundationDB server.
You also must to ensure that your application instance has sufficient network access to the FDB servers.
Radical: application manages its own database cluster
Alternatively, your app's production config can bootstrap its own multi-node FoundationDB cluster. ex_fdbmontior
makes it easy to use the BEAM's clustering capabilities for node discovery. There are a couple reasons why you
might consider this approach.
	You simply want a local single-node FDB database, similar to a SQLite deployment.
	Your applicatiion needs multi-node ACID transactions, and you don't want the complexity or cost
associated with hosting a separate database.
	You run a deployment of your application that acts as the database and a deployment that acts as the
stateless application. Similar to the approach used by FLAME, you could create a MIX_ENV=db
variant of your app that runs ex_fdbmonitor and bootstraps the database, whereas MIX_ENV=prod
simply connects to it.
	You create an entirely separate Elixir app that is strictly concerned with running ex_fdbmonitor.
Once such an application is running, your main application can use the Conventional approach.

In any of these cases, your runtime.exs could resemble something like this:
# config/runtime.exs
import Config

database_path = System.fetch_env!("DATABASE_PATH")

config :ex_fdbmonitor,
  etc_dir: Path.join(database_path, "etc"),
  run_dir: Path.join(database_path, "run")

interface = System.get_env("EXAMPLE_APP_COORDINATOR_IF", "en0")

{:ok, addrs} = :inet.getifaddrs()

coordinator_addr =
  addrs
  |> then(&:proplists.get_value(~c"#{interface}", &1))
  |> then(&:proplists.get_all_values(:addr, &1))
  |> Enum.filter(&(tuple_size(&1) == 4))
  |> hd()
  |> :inet.ntoa()
  |> to_string()

config :ex_fdbmonitor,
  bootstrap: [
    cluster: [
      coordinator_addr: coordinator_addr
    ],
    conf: [
      data_dir: "/var/lib/example_app/data/fdb/data",
      log_dir: "/var/lib/example_app/data/fdb/log",
      storage_engine: "ssd-2",
      fdbservers: [port: 4500, port: 4501],
      redundancy_mode: "double"
    ]
  ]
and prod.exs:
# config/prod.exs
config :example_app, ExampleApp.Repo,
  open_db: &ExFdbmonitor.open_db/1
# ...
Keep in mind that :erlang.nodes() is used to detect nodes that any given node can join to in
order to form the cluster on first boot. So your nodes must be able to reach each other.
On first bring-up, nodes should be started individually and serially.
Once a given node has been started, the bootstrap config will be ignored on all subsequent restarts.
The first node to start (with no connected peers) will create the cluster and run
configure new single <storage_engine>. Subsequent nodes will automatically join via
the existing peers. Once enough nodes are registered, redundancy_mode takes effect.
Schemas and Migrations
For completeness, we'll give our ExampleApp a Schema to write data to and give it an index via a Migration.
We suggest the reader consult the EctoFoundationDB documentation for details regarding Schemas, Indexes,
and Migrations. We'll provide a minimal set-up here to get you started.
Schema
Defines a struct your app stores in the database.
# lib/example_app/temperature_event.ex
defmodule ExampleApp.TemperatureEvent do
  use Ecto.Schema
  @primary_key {:id, :binary_id, autogenerate: true}

  schema "temperature_events" do
    field(:recorded_at, :naive_datetime_usec)
    field(:kelvin, :float)
    field(:site, :string)
    timestamps()
  end
end
Indexes
Defines the fields that can be used to efficiently access your data.
Remember: all EctoFoundationDB.Migration modules must be included in your application release.
# lib/example_app/migrations/temperature_event_indexes.ex
defmodule ExampleApp.Migrations.TemperatureEventIndexes do
  use EctoFoundationDB.Migration
  alias ExampleApp.TemperatureEvent

  def change() do
    [
      create(index(TemperatureEvent, [:site])),
      create(index(TemperatureEvent, [:recorded_at]))
    ]
  end
end
Migration
Defines the order in which the indexes are created and the corresponding monotonically increasing version numbers.
Remember: your EctoFoundationDB.Migrator module must be included in your application release.
# lib/example_app/repo.ex
defmodule ExampleApp.Repo do
  # ...

  use EctoFoundationDB.Migrator
  def migrations() do
    [{0, ExampleApp.Migrations.TemperatureEventIndexes}]
  end
end
Test
Finally, we can write some data!
# test/example_app_test.exs
defmodule ExampleAppTest do
  use ExampleApp.TenantCase
  alias ExampleApp.TemperatureEvent
  alias ExampleApp.Repo

  test "greets the world", context do
    tenant = context[:tenant]

    event =
      Repo.insert!(
        %TemperatureEvent{kelvin: 13.37, site: "L2", recorded_at: NaiveDateTime.utc_now()},
        prefix: tenant
      )

    assert %TemperatureEvent{site: "L2"} = event

    assert ^event = Repo.get_by!(TemperatureEvent, [site: "L2"], prefix: tenant)
  end
end

ExFdbmonitor starts and supervises fdbmonitor (the FoundationDB management
process), bootstraps new clusters, and handles scaling operations — all
coordinated across nodes via Erlang distribution.
How it works
	First node — detects that no FDB peers exist, creates the cluster file,
writes a foundationdb.conf, and runs configure new single <storage_engine>.
	Subsequent nodes — discover existing peers via :erlang.nodes(), copy
the cluster file, and join the cluster.
	Redundancy — once enough nodes are registered, scale_up configures
coordinators and the declared redundancy mode ("double", "triple").
	Restarts — on restart the bootstrap config is ignored (data files
already exist). The node re-includes itself if necessary and re-evaluates
redundancy automatically.

All mutating FDB operations are serialized through ExFdbmonitor.MgmtServer, a
DGenServer backed by FDB itself.
This prevents concurrent fdbcli commands from interleaving across nodes.
Requirements
	Elixir ~> 1.18
	FoundationDB client and server packages
(releases)

Usage
See examples/example_app/README.md for a tutorial on
using ExFdbmonitor in your application.
Configuration
FDB executable paths
ExFdbmonitor resolves FDB binary paths automatically based on the OS (Darwin and
Linux are supported). If your installation is in a non-standard location, override
any path explicitly:
config :ex_fdbmonitor,
  fdbmonitor: "/custom/path/fdbmonitor",
  fdbcli: "/custom/path/fdbcli",
  fdbserver: "/custom/path/fdbserver",
  fdbdr: "/custom/path/fdbdr",
  backup_agent: "/custom/path/backup_agent",
  dr_agent: "/custom/path/dr_agent"
Default paths by OS:
	Binary	macOS	Linux
	fdbmonitor	/usr/local/libexec/fdbmonitor	/usr/sbin/fdbmonitor
	fdbcli	/usr/local/bin/fdbcli	/usr/bin/fdbcli
	fdbserver	/usr/local/libexec/fdbserver	/usr/sbin/fdbserver
	fdbdr	/usr/local/bin/fdbdr	/usr/bin/fdbdr
	backup_agent	/usr/local/foundationdb/backup_agent/backup_agent	/usr/lib/foundationdb/backup_agent/backup_agent
	dr_agent	/usr/local/bin/dr_agent	/usr/lib/foundationdb/backup_agent/backup_agent

Minimal (single-node dev)
# config/dev.exs
import Config

config :ex_fdbmonitor,
  etc_dir: ".my_app/dev/fdb/etc",
  run_dir: ".my_app/dev/fdb/run"

config :ex_fdbmonitor,
  bootstrap: [
    conf: [
      data_dir: ".my_app/dev/fdb/data",
      log_dir: ".my_app/dev/fdb/log",
      fdbservers: [[port: 5000]]
    ]
  ]
Multi-node production
# config/runtime.exs
import Config

addr = fn interface ->
  {:ok, addrs} = :inet.getifaddrs()
  :proplists.get_value(to_charlist(interface), addrs)[:addr]
  |> :inet.ntoa()
  |> to_string()
end

config :ex_fdbmonitor,
  etc_dir: "/var/lib/my_app/fdb/etc",
  run_dir: "/var/lib/my_app/fdb/run"

config :ex_fdbmonitor,
  bootstrap: [
  
    # nodes must communicate with coordinators over the
    # network interface
    cluster: [coordinator_addr: addr.("eth0")],
    
    conf: [
      data_dir: "/var/lib/my_app/fdb/data",
      log_dir: "/var/lib/my_app/fdb/log",
      storage_engine: "ssd-2",
      
      # We're defining 2 fdbservers per node
      fdbservers: [[port: 4500], [port: 4501]],
      
      # When safe to do so, ex_fdbmonitor will upgrade
      # to 'double' redunancy automatically
      redundancy_mode: "double"
    ]
  ]
Configuration reference
	Key	Required	Description
	:etc_dir	yes	Directory for fdb.cluster and foundationdb.conf
	:run_dir	yes	Directory for fdbmonitor pid file
	:bootstrap	no	Bootstrap config (ignored after first successful start)

Bootstrap keys:
	Key	Description
	cluster: [coordinator_addr:]	IP address for the initial coordinator (default "127.0.0.1")
	conf: [data_dir:]	FDB data directory
	conf: [log_dir:]	FDB log directory
	conf: [storage_engine:]	Storage engine (default "ssd-2")
	conf: [fdbservers:]	List of [port: N] keyword lists, one per fdbserver process
	conf: [redundancy_mode:]	"single", "double", or "triple" (default: nil / single)
	fdbcli:	Extra fdbcli args to run at bootstrap (optional, repeatable)

Bootstrap flow
On application start, ExFdbmonitor runs two phases:
Phase 1 (before any processes start):
	If the conf file and data dir are empty (first boot), write config files.
If FDB peers exist on :erlang.nodes(), copy their cluster file.
Otherwise, create a new cluster file and generate configure new single <engine>.
	If files already exist (restart), skip — use existing cluster file.

Phase 2 (after fdbmonitor / fdbserver are running):
	Start ExFdbmonitor.MgmtServer (connects to FDB for distributed coordination).
	Register this node's machine_id.
	Call scale_up(redundancy_mode, [node()]) — includes the node back
into FDB and configures redundancy when enough nodes are present.

Public API
ExFdbmonitor.leave/0
Gracefully remove the current node from the cluster. Downgrades redundancy
if needed, reassigns coordinators, excludes the node (blocks until data is
moved), and stops the local fdbmonitor. To rejoin, restart the
:ex_fdbmonitor application.
Redundancy modes
	Mode	Min nodes	Min coordinators
	"single"	1	1
	"double"	3	3
	"triple"	5	5

scale_up stores the declared mode as a ceiling. scale_down
auto-determines the highest mode the surviving nodes can support, capped
at that ceiling. This prevents a scale-down/scale-up cycle from
accidentally exceeding the operator's intent.
Scaling example
When a node is gracefully shutting down,
# On the departing node:
ExFdbmonitor.leave()
When a node is returning from previously having been gracefully shutdown,
# Later, restart the :ex_fdbmonitor application to rejoin:
Application.stop(:ex_fdbmonitor)
Application.ensure_all_started(:ex_fdbmonitor)
Testing
ExFdbmonitor provides sandbox modules for integration testing:
# Single-node sandbox
sandbox = ExFdbmonitor.Sandbox.Single.checkout("my-test", starting_port: 5000)
# ... run tests ...
ExFdbmonitor.Sandbox.Single.checkin(sandbox, drop?: true)

# 3-node double-redundancy sandbox
sandbox = ExFdbmonitor.Sandbox.Double.checkout("my-test", starting_port: 5500)
# ... run tests ...
ExFdbmonitor.Sandbox.Double.checkin(sandbox, drop?: true)
Sandboxes start isolated local_cluster nodes with their own FDB
processes. Pass drop?: true to delete all data on checkin.
Usage
See examples/example_app/README.md for a tutorial on
using ExFdbmonitor in your application.

        Gracefully remove the current node from the cluster.

        Opens a database connection.

Gracefully remove the current node from the cluster.
Executes MgmtServer.scale_down/1 which, under the DGen.Server lock:
	Downgrades the redundancy mode if the remaining nodes can no longer
sustain it (e.g. triple → double when dropping below 5 nodes).
	Reassigns coordinators to surviving nodes.
	Excludes this node's FDB processes (blocks until data is fully moved).

If the exclude succeeds the local worker is terminated
so that fdbmonitor and its fdbserver processes are stopped.
Returns :ok on success or {:error, reason} if the scale-down fails
(in which case the worker is left running).
Rejoining after leave
Restart the :ex_fdbmonitor application.  The bootstrap flow will
detect that data files already exist, skip the initial configure,
and call MgmtServer.scale_up/2 which includes the node back into
FDB and reconfigures the redundancy mode if the cluster now has
enough nodes.

Opens a database connection.
Arguments
	:input: Ignored. It's here for compatibility with other libraries.

Examples
Use whenever you need to open the t:erlfdb.database/0:
db = ExFdbmonitor.open_db()
"world" = :erlfdb.get(db, "hello")
Use in conjuncation with Ecto.Adapters.FoundationDB:
config :my_app, MyApp.Repo,
  open_db: &ExFdbmonitor.open_db/1

Resolves paths to FoundationDB binaries.
A path configured via Application.get_env/3 always takes precedence.
Otherwise the default for the current OS is used.
Supported systems: Darwin (macOS) and Linux. Windows is not supported.
Configuration
Override any binary path in your application config:
config :ex_fdbmonitor,
  fdbmonitor: "/custom/path/fdbmonitor",
  fdbcli: "/custom/path/fdbcli",
  fdbserver: "/custom/path/fdbserver",
  fdbdr: "/custom/path/fdbdr",
  backup_agent: "/custom/path/backup_agent",
  dr_agent: "/custom/path/dr_agent"
OS defaults
	Binary	macOS	Linux
	fdbmonitor	/usr/local/libexec/fdbmonitor	/usr/lib/foundationdb/fdbmonitor
	fdbcli	/usr/local/bin/fdbcli	/usr/bin/fdbcli
	fdbserver	/usr/local/libexec/fdbserver	/usr/sbin/fdbserver
	fdbdr	/usr/local/bin/fdbdr	/usr/bin/fdbdr
	backup_agent	/usr/local/foundationdb/backup_agent/backup_agent	/usr/lib/foundationdb/backup_agent/backup_agent
	dr_agent	/usr/local/bin/dr_agent	/usr/bin/dr_agent

This module provides functions for executing fdbcli commands.
Options
All exec variants accept an optional opts keyword list:
	:timeout - maximum time in milliseconds to wait for fdbcli to complete.
When set, the OS process is killed if it does not finish within the
allotted time.

	:stderr - whether to capture stderr (default true). Set to false
when only stdout is needed, e.g. when parsing structured output like JSON.

        Run a fdbcli command against the current node's cluster file.



    


    
      
        exec(cluster_file, fdbcli_exec)

      


        Run a fdbcli command against the given cluster file.



    


    
      
        exec(cluster_file, fdbcli_exec, opts)

      


        Run a fdbcli command against the given cluster file with options.

Run a fdbcli command against the current node's cluster file.

Run a fdbcli command against the given cluster file.

Run a fdbcli command against the given cluster file with options.

This module provides functions for executing fdbdr commands.

A DGen.Server that serializes actions across all nodes.
Nodes submit fdbcli commands via exec/1. The DGen.Server processes
them one at a time, ensuring commands from different nodes don't
interleave on a cluster that is still being configured.

        adopt_node(machine_id, node_name)

      


        Register node_name as the node for machine_id, unless that machine_id
already belongs to a different node.



    


    
      
        child_spec(init_arg)

      


        Returns a specification to start this module under a supervisor.



    


    
      
        exclude(node_name)

      


        Exclude all FDB processes belonging to node_name from the cluster.



    


    
      
        exec(fdbcli_args)

      


        Execute fdbcli_args through the serialized server.



    


    
      
        get_machine_id(node_name)

      


        Look up the machine_id for a given node name.



    


    
      
        include(node_name)

      


        Include all FDB processes belonging to node_name back into the cluster.



    


    
      
        register_node(machine_id, node_name)

      


        Register a mapping from machine_id to node_name in the server state.



    


    
      
        scale_down(nodes_to_exclude)

      


        Gracefully remove nodes_to_exclude from the cluster.



    


    
      
        scale_up(target_mode, nodes_to_include)

      


        Declare the desired redundancy mode and configure when ready.

Register node_name as the node for machine_id, unless that machine_id
already belongs to a different node.
For a node that was not registered at bootstrap, such as one in a cluster
bootstrapped before MgmtServer existed. Returns :ok if the node is now
registered, or was already, and {:error, {:machine_id_taken, other_node}}
if another node holds the machine_id, as when a node's name has changed.

Returns a specification to start this module under a supervisor.
See Supervisor.

Exclude all FDB processes belonging to node_name from the cluster.
Raises if the node has no registered machine_id.

Execute fdbcli_args through the serialized server.

Look up the machine_id for a given node name.

  



  
    
      
    
    
      include(node_name)



        
          
        

    

  


  

Include all FDB processes belonging to node_name back into the cluster.
Returns {:error, {:unknown_node, node_name}} if the node has no registered machine_id.

Register a mapping from machine_id to node_name in the server state.

  



  
    
      
    
    
      scale_down(nodes_to_exclude)



        
          
        

    

  


  

Gracefully remove nodes_to_exclude from the cluster.
Automatically determines the appropriate redundancy mode for the
surviving nodes and downgrades if necessary. Executes under the
DGen.Server lock:
	configure <mode> (only if downgrade needed)
	Set coordinators to surviving nodes
	exclude each departing node (blocks until data moved)

The caller is responsible for stopping workers on the removed nodes
after this call returns.

Declare the desired redundancy mode and configure when ready.
When target_mode is non-nil it is stored as the redundancy ceiling.
When target_mode is nil the previously stored mode is used (also
nil is fine — the call becomes a no-op).
nodes_to_include is a list of node names to include back into FDB
before configuring (e.g. after a previous exclude).
If enough nodes are registered (@min_nodes), acquires the lock and
runs include → coordinators auto → configure <mode>.  Calls
before the threshold is met are no-ops.

ExFdbmonitor.Sandbox 
    



      
Build a sandbox FoundationDB cluster.
Examples
alias ExFdbmonitor.Sandbox

Sandbox.start()
cluster_file = Sandbox.cluster_file("dev", 0)
sandbox = Sandbox.Single.checkout("dev", starting_port: 5050)
IO.puts("Cluster file: #{cluster_file}")
_anything = IO.gets("Input anything to stop FDB: ")
Sandbox.Single.checkin(sandbox)

ExFdbmonitor.Sandbox.Double 
    



      
This module provides functions for managing multi-node FoundationDB sandboxes in double redundancy mode.

ExFdbmonitor.Sandbox.Single 
    



      
This module provides functions for managing single-node FoundationDB sandboxes.
All sandbox processes run on the same machine and bind fdbserver to
127.0.0.1 so that the cluster file coordinator address and the fdbserver
listen address always match, regardless of the host's outbound IP.

ExFdbmonitor.Sandbox.Triple 
    



      
This module provides functions for managing multi-node FoundationDB sandboxes in triple redundancy mode.

